Check of Panel Profile
The Toruń 32 m radio telescope (RT32) is being equipped
with receivers,
such as the OCRA,
for ever higher frequencies approaching the projected limits conditioned
by the accuracy of main dish surface and coordinate measurements
(pointing accuracy). This requires careful reanalysis of telescope
properties (see e.g. this
document) and use of special techniques (such as the holography).
As part of this endevour a simple test has been performed to see how close
the shape of panels of the telescope assumed during their fabrication
is consistent with paraboloid of revolution of the RT32 design. Possible
errors inherent in the manufacturing process might make futile any attempts
to considerably improve the telescope efficiency at high frequencies.
The method employed here relies on transformation of array of panel depths defined relative to the plane passing through all 4 corners of a panel (the reference plane used during construction of the RT32) onto distances counted from the aperture plane passing through the paraboloid vertex. Originally, calculations of the panel profiles for manufacturing and measurements was based on the algorithm implemented in the Fortran routine PANEL (in fact, in its 1990 version, which however had the same core; the presented version has been edited for better readability). The mentioned transformation assumes only known placement (distance from the paraboloid axis and inclination of the reference plane) of the panel analysed and actually reduces to simple rotation. None of the paraboloid parameters is used in this process in a way that could influence the panel profile described by the given depths (and thus making this test invalid). The distances so obtained from the depths are then compared directly with those calculated for the perfect RT32 paraboloid of revolution. Details are given as comments in the following program code itself.
program PANEL_Check
c This program checks if the depths of RT32 panels, representing their
c profile during fabrication and later accuracy measurements, indeed fit
c to the paraboloid of revolution defined in the telescope project.
c This version works only for the panel No 5, but can be easily adapted
c to check other panels (to this end a data file similar to Panel5.dat
c should be prepared, basing on the available archival documentation
c of 1992/1993 by Karol Borkowy)
implicit real*8 (a-h,o-z)
dimension depth(11,9),xifirst(7),Ro(8),nj(7)
c Origin of measurement array as inferred from old documentation [mm];
c these estimates (except for panel No 5) can be in error of up to ~1 mm.
data xifirst/58d0,57d0,57d0,56.5d0,49.1d0,49d0,15.5d0/,
c Radii of parallels separating panel rings [mm]
* Ro/16d3,14142.91d0,12213.76d0,10212.36d0,8141.38d0,
* 6007.36d0,3821.53d0,16d2/
data nj/4*64,2*32,16/ ! number of panels in rings
C Only panel No 5 is checked here. File Panel5.dat contains depths
c of this panel relative to the plane through its corners. These
c theoretical depths were used as reference for panel accuracy
c determination after manufacturing in 1992/93. The same data were
c partly reproduced (in blue) as an example in this web page table
c (the existence of the above reference was the sole reason for
c chosing this particular panel for the presented check).
c To test other panels modify the following two lines:
NRpan = 5 ! Panel numer (1 stands for the outermost)
open(1,'Panel5.dat',status='old')
Nx = 9 ! longitudinal dimension of array of points
Ny = 11 ! lateral dimension
read(1,'(////)') ! skip textual header
do 1 i = 1,Nx
1 read(1,*) (depth(j,i), j = 1,Ny)
close(1)
xistep= 265 ! row separation [mm] (lengthwise)
ystep = 150 ! column separation [mm]
c Cosine of half of angle between meridians limiting this panel;
c there are 32 panels in this ring so that P=360/(2*32) degrees
cosP = dcos(3.141592653589d0/nj(Nrpan))
f = 11200d0 ! RT32 focal distance [mm]
c Inclination of reference plane with respect to aperture plane
E = datan((Ro(Nrpan) + Ro(Nrpan+1))/(4*f*cosP))
c Height of outer panel corners above the parabola vertex
Z0 = Ro(Nrpan)**2/(4*f)
do 10 iy = 1,Ny ! array column index
c Distance of reference point from meridian plane passing through
c middle of this panel (same as table column position on reference
c plane)
y = (iy - 6)*ystep
do 10 ix = 1,Nx ! array row index
const=1d9 ! large number to mark omitted points
c Omit points outside the panel
if(depth(iy,ix).le.0d0) go to 10
c Row position on reference plane
xi = xifirst(NRpan) + (ix-1)*xistep
c x-coordinate on aperture plane of point on panel surface which
c lies 'depth' below corresponding point on the reference plane
x = Ro(Nrpan)*cosP - xi*dcos(E) + depth(iy,ix)*dsin(E)
c Squared radial distance of this point (on panel) from paraboloid axis
Rsq = x**2 + y**2
c z-coordinate (parallel to paraboloid axis) of the point on panel
zp = Z0 - xi*dsin(E) - depth(iy,ix)*dcos(E)
c For perfect panel this coordinate should differ only by a constant
c from the one calculated using equation of dish parabola
const = zp - Rsq/(4*f)
sum = sum + const
Number = Number + 1
10 depth(iy,ix) = const
c Remove mean value from the differences
average = sum/Number
do 20 ix = 1,Nx
do 20 iy = 1,Ny
20 depth(iy,ix) = depth(iy,ix) - average
write(*,'(5x," Mean:",f7.3/(11(1x,f6.2)))') average,depth
end
|
Running an executable of this program results in the following output:
Mean: -0.031 0.00 0.01 0.01 0.00 0.00 0.00 0.00 0.00 0.01 0.01 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 -0.01 -0.01 0.00 0.00 0.00 -0.01 -0.01 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 -0.01 0.00 0.00 -0.01 0.00 0.00 0.00 -0.01 0.00 0.00 -0.01 0.00 -0.01 0.00 0.00 -0.01 -0.01 -0.01 0.00 0.00 -0.01 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 0.00 ****** 0.01 0.01 0.00 0.01 0.00 0.01 0.00 0.01 0.01 ****** |
Thus the differences are nearly constant, which means that the depths read in do precisely follow the paraboloidal shape, down to their least significant digit (0.01 mm). The small departures could safely be ascribed to finite precision of the depths, uncertainty in the estimate of origin of longitudinal coordinate on the panel reference plane, and round off errors.
This optimistic result, of course, does not imply high actual panel accuracies. It only presents a solid evidence that there are no systematic displacements due to errors in panel profiles assumed during production process, similar to those that affected the Hubble telescope.
Content of the file 'Panel5.dat' read by 'PANEL_Check' program
(the red lines do not belong to the file)
|
— KMB
Posted 2004, May 23 last modified 2004, June 1